L298N-Motortreiber – Arduino-Schnittstelle, Funktionsweise, Codes, Schaltpläne

Beschreibung: Also müssen wir zuerst die Pins und einige Variablen definieren, die für das Programm benötigt werden. Im Setup-Bereich müssen wir die Pin-Modi und die anfängliche Drehrichtung des Motors einstellen. Im Schleifenabschnitt beginnen wir mit dem Lesen des Potentiometerwerts und ordnen dann den Wert, den wir daraus erhalten, der von 0 bis 1023 geht, einem Wert von 0 bis 255 für das PWM-Signal zu, oder das ist 0 bis 100 % Arbeitszyklus des PWM-Signal. Dann senden wir mit der Funktion analogWrite() das PWM-Signal an den Enable-Pin der L298N-Platine, die den Motor tatsächlich antreibt.

Als nächstes prüfen wir, ob wir die Taste gedrückt haben, und wenn das stimmt, ändern wir die Drehrichtung des Motors, indem wir die Zustände von Eingang 1 und Eingang 2 invertieren. Der Druckknopf funktioniert als Umschaltknopf und jedes Mal, wenn wir ihn drücken, ändert er die Drehrichtung des Motors.

Arduino-Roboterautosteuerung mit L298N-Motortreiber

Sobald wir das gelernt haben, können wir jetzt unser eigenes Arduino-Roboterauto bauen. Hier ist der Schaltplan:

Alles, was wir brauchen, sind 2 Gleichstrommotoren, der L298N-Motortreiber, ein Arduino-Board und ein Joystick für die Steuerung. Für die Stromversorgung habe ich mich für drei 3,7-V-Li-Ionen-Batterien entschieden, die insgesamt 11 V liefern. Das Chassis habe ich aus 3 mm dickem Sperrholz gefertigt, die Motoren mit Metallklammern daran befestigt, Räder an den Motoren befestigt und vorne ein Schwenkrad angebracht.

Schauen wir uns nun den Arduino-Code an und sehen, wie er funktioniert. (Unten finden Sie den vollständigen Code)

int xAxis = analogRead(A0); // Read Joysticks X-axis
int yAxis = analogRead(A1); // Read Joysticks Y-axis Codesprache:Arduino (arduino) 

Nachdem wir die Pins definiert haben, beginnen wir im Schleifenabschnitt mit dem Lesen der X- und Y-Achsenwerte des Joysticks. Der Joystick besteht eigentlich aus zwei Potentiometern, die mit den analogen Eingängen des Arduino verbunden sind und Werte von 0 bis 1023 haben. Wenn der Joystick in seiner Mittelposition bleibt, beträgt der Wert beider Potentiometer oder Achsen etwa 512.

Wir werden eine kleine Toleranz hinzufügen und die Werte von 470 bis 550 als Mitte betrachten. Wenn wir also die Y-Achse des Joysticks nach hinten bewegen und der Wert unter 470 fällt, setzen wir die Drehrichtung der beiden Motoren mithilfe der vier Eingangspins auf rückwärts. Dann werden wir die fallenden Werte von 470 bis 0 in steigende PWM-Werte von 0 bis 255 umwandeln, was eigentlich die Drehzahl des Motors ist.

// Y-axis used for forward and backward control
  if (yAxis < 470) {
    // Set Motor A backward
    digitalWrite(in1, HIGH);
    digitalWrite(in2, LOW);
    // Set Motor B backward
    digitalWrite(in3, HIGH);
    digitalWrite(in4, LOW);
    // Convert the declining Y-axis readings for going backward from 470 to 0 into 0 to 255 value for the PWM signal for increasing the motor speed
    motorSpeedA = map(yAxis, 470, 0, 0, 255);
    motorSpeedB = map(yAxis, 470, 0, 0, 255);
  } Codesprache:Arduino (arduino) 

Ähnlich, wenn wir die Y-Achse des Joysticks nach vorne bewegen und der Wert über 550 geht, werden wir die Motoren so einstellen, dass sie sich vorwärts bewegen und die Messwerte von 550 bis 1023 in PWM-Werte von 0 bis 255 umwandeln Motorgeschwindigkeit wird Null sein.

Als nächstes sehen wir uns an, wie wir die X-Achse für die linke und rechte Steuerung des Autos verwenden.

// X-axis used for left and right control
  if (xAxis < 470) {
    // Convert the declining X-axis readings from 470 to 0 into increasing 0 to 255 value
    int xMapped = map(xAxis, 470, 0, 0, 255);
    // Move to left - decrease left motor speed, increase right motor speed
    motorSpeedA = motorSpeedA - xMapped;
    motorSpeedB = motorSpeedB + xMapped;
    // Confine the range from 0 to 255
    if (motorSpeedA < 0) {
      motorSpeedA = 0;
    }
    if (motorSpeedB > 255) {
      motorSpeedB = 255;
    }
  } Codesprache:Arduino (arduino) 

Also müssen wir zuerst die Messwerte der X-Achse in Geschwindigkeitswerte von 0 bis 255 umwandeln. Für die Bewegung nach links verwenden wir diesen Wert, um die linke Motorgeschwindigkeit zu verringern und die rechte Motorgeschwindigkeit zu erhöhen. Hier verwenden wir wegen der arithmetischen Funktionen zwei zusätzliche „if“-Anweisungen, um den Bereich der Motordrehzahl von 0 bis 255 einzuschränken.

Die gleiche Methode wird verwendet, um das Auto nach rechts zu bewegen.

Siehe auch: So erstellen Sie einen PWM-DC-Motordrehzahlregler mit dem 555-Timer-IC

Abhängig von der angelegten Spannung und dem Motor selbst kann der Motor bei niedrigeren Drehzahlen nicht in Bewegung kommen und erzeugt ein brummendes Geräusch. In meinem Fall konnten sich die Motoren nicht bewegen, wenn der Wert des PWM-Signals unter 70 lag. Daher habe ich mich mit diesen beiden if-Anweisungen tatsächlich auf den Geschwindigkeitsbereich von 70 bis 255 beschränkt. Am Ende senden wir nur die endgültigen Motorgeschwindigkeiten oder PWM-Signal an die Enable-Pins des L298N-Treibers.

// Prevent buzzing at low speeds (Adjust according to your motors. My motors couldn't start moving if PWM value was below value of 70)
  if (motorSpeedA < 70) {
    motorSpeedA = 0;
  }
  if (motorSpeedB < 70) {
    motorSpeedB = 0;
  }
  analogWrite(enA, motorSpeedA); // Send PWM signal to motor A
  analogWrite(enB, motorSpeedB); // Send PWM signal to motor B Codesprache:Arduino (arduino) 

Hier ist der vollständige Code des Arduino-Roboterauto-Beispiels:

/*  Arduino DC Motor Control - PWM | H-Bridge | L298N
         Example 02 - Arduino Robot Car Control
    by Dejan Nedelkovski, www.HowToMechatronics.com
*/

#define enA 9
#define in1 4
#define in2 5
#define enB 10
#define in3 6
#define in4 7

int motorSpeedA = 0;
int motorSpeedB = 0;

void setup() {
  pinMode(enA, OUTPUT);
  pinMode(enB, OUTPUT);
  pinMode(in1, OUTPUT);
  pinMode(in2, OUTPUT);
  pinMode(in3, OUTPUT);
  pinMode(in4, OUTPUT);
}

void loop() {
  int xAxis = analogRead(A0); // Read Joysticks X-axis
  int yAxis = analogRead(A1); // Read Joysticks Y-axis

  // Y-axis used for forward and backward control
  if (yAxis < 470) {
    // Set Motor A backward
    digitalWrite(in1, HIGH);
    digitalWrite(in2, LOW);
    // Set Motor B backward
    digitalWrite(in3, HIGH);
    digitalWrite(in4, LOW);
    // Convert the declining Y-axis readings for going backward from 470 to 0 into 0 to 255 value for the PWM signal for increasing the motor speed
    motorSpeedA = map(yAxis, 470, 0, 0, 255);
    motorSpeedB = map(yAxis, 470, 0, 0, 255);
  }
  else if (yAxis > 550) {
    // Set Motor A forward
    digitalWrite(in1, LOW);
    digitalWrite(in2, HIGH);
    // Set Motor B forward
    digitalWrite(in3, LOW);
    digitalWrite(in4, HIGH);
    // Convert the increasing Y-axis readings for going forward from 550 to 1023 into 0 to 255 value for the PWM signal for increasing the motor speed
    motorSpeedA = map(yAxis, 550, 1023, 0, 255);
    motorSpeedB = map(yAxis, 550, 1023, 0, 255);
  }
  // If joystick stays in middle the motors are not moving
  else {
    motorSpeedA = 0;
    motorSpeedB = 0;
  }

  // X-axis used for left and right control
  if (xAxis < 470) {
    // Convert the declining X-axis readings from 470 to 0 into increasing 0 to 255 value
    int xMapped = map(xAxis, 470, 0, 0, 255);
    // Move to left - decrease left motor speed, increase right motor speed
    motorSpeedA = motorSpeedA - xMapped;
    motorSpeedB = motorSpeedB + xMapped;
    // Confine the range from 0 to 255
    if (motorSpeedA < 0) {
      motorSpeedA = 0;
    }
    if (motorSpeedB > 255) {
      motorSpeedB = 255;
    }
  }
  if (xAxis > 550) {
    // Convert the increasing X-axis readings from 550 to 1023 into 0 to 255 value
    int xMapped = map(xAxis, 550, 1023, 0, 255);
    // Move right - decrease right motor speed, increase left motor speed
    motorSpeedA = motorSpeedA + xMapped;
    motorSpeedB = motorSpeedB - xMapped;
    // Confine the range from 0 to 255
    if (motorSpeedA > 255) {
      motorSpeedA = 255;
    }
    if (motorSpeedB < 0) {
      motorSpeedB = 0;
    }
  }
  // Prevent buzzing at low speeds (Adjust according to your motors. My motors couldn't start moving if PWM value was below value of 70)
  if (motorSpeedA < 70) {
    motorSpeedA = 0;
  }
  if (motorSpeedB < 70) {
    motorSpeedB = 0;
  }
  analogWrite(enA, motorSpeedA); // Send PWM signal to motor A
  analogWrite(enB, motorSpeedB); // Send PWM signal to motor B
} Codesprache:Arduino (arduino) 

Das wäre also alles für dieses Tutorial, und in meinem nächsten Video werden wir dieses Arduino-Roboterauto aufrüsten, indem wir Bluetooth- und Funkgeräte hinzufügen, um Smartphones und drahtlose Steuerung zu ermöglichen.

Fühlen Sie sich frei, Fragen in den Kommentaren unten zu stellen, und vergessen Sie nicht, meine Sammlung von Arduino-Projekten zu überprüfen.