Verilog-Zeitformat

Die Verilog-Zeitskalendirektive spezifiziert Zeiteinheit und Genauigkeit für Simulationen.

Verilog $timeformat Systemfunktion spezifiziert %t Berichtsstil für Formatbezeichner in Anzeigeanweisungen wie $display und $strobe .

Syntax

  
  
$timeformat(<unit_number>, <precision>, <suffix_string>, <minimum field width>);

  

• unit_number ist die kleinste Zeitgenauigkeit von allen `timescale Direktiven, die im Quellcode verwendet werden
• Präzision stellt die Anzahl der Nachkommastellen für die aktuelle Zeitskala dar
• suffix_string ist eine Option, um die Skala neben den Echtzeitwerten anzuzeigen

Einheitsnummer	Zeiteinheit
-3	1ms
-6	1us
-9	1ns
-12	1ps
-15	1fs

Beispiel #1:1ns/1ps

Hier ist ein Beispiel dafür, wie $timeformat beeinflusst das Anzeigeformat der Zeiteinheit.

  
  
`timescale 1ns/1ps

module tb;
  bit 	a;
  
  initial begin
    
    // Wait for some time - note that because precision is 1/1000 of
    // the main scale (1ns), this delay will be truncated by the 3rd
    // position
    #10.512351;
    
    // Display current time with default timeformat parameters
    $display("[T=%0t] a=%0b", $realtime, a);
    
    // Change timeformat parameters and display again
    $timeformat(-9, 2, " ns");
    $display("[T=%0t] a=%0b", $realtime, a);
    
    // Remove the space in suffix, and extend fractional digits to 5
    $timeformat(-9, 5, "ns");
    $display("[T=%0t] a=%0b", $realtime, a);
    
    // Here suffix is wrong, it should not be "ns" because we are
    // setting display in "ps" (-12) 
    $timeformat(-12, 3, " ns");
    $display("[T=%0t] a=%0b", $realtime, a);
    
    // Correct the suffix to ps
    $timeformat(-12, 2, " ps");
    $display("[T=%0t] a=%0b", $realtime, a);
  end
endmodule

  

Simulationsprotokoll

xcelium> run
[T=10512] a=0
[T=10.51 ns] a=0
[T=10.51200ns] a=0
[T=10512.000 ns] a=0
[T=10512.00 ps] a=0
xmsim: *W,RNQUIE: Simulation is complete.

Beispiel #2:1ns/100ps

Hier ist dasselbe Beispiel von oben mit einer anderen Zeitskala.

  
  
`timescale 1ns/100ps

  

Simulationsprotokoll

xcelium> run
[T=105] a=0
[T=10.50 ns] a=0
[T=10.50000ns] a=0
[T=10500.000 ns] a=0
[T=10500.00 ps] a=0
xmsim: *W,RNQUIE: Simulation is complete.

Beispiel #3:100ns/1ns

  
  
`timescale 100ns/1ns

  

#1 steht für 100ns und somit ergibt #10 1000ns

Simulationsprotokoll

xcelium> run
[T=1051] a=0
[T=1051.00 ns] a=0
[T=1051.00000ns] a=0
[T=1051000.000 ns] a=0
[T=1051000.00 ps] a=0
xmsim: *W,RNQUIE: Simulation is complete.