Präziser Joystick-Controller für MeArm-Roboter: Koordinaten aufzeichnen & wiedergeben

Komponenten und Zubehör

Software und Online-Dienste

• Arduino IDE

Projektbeschreibung

Ein Arduino-Uno-basierter Joystick-Controller für den MeArm®-Roboterarm mit Aufzeichnung und Wiedergabe von Koordinaten. Das System funktioniert ohne zusätzliche Shields – nur das Arduino-Basisboard. Stromversorgung per USB (2 A) oder 6 V / 2 A Netzteil. Getestet mit vier SG90-Servos.

Bedienung

• Joystick 1 (Basis & Schulter): Bewegt Greifer vor/rück, links/rechts. Taster: Aufnahme starten/stoppen.
• Joystick 2 (Ellbogen & Greifer): Bewegt Greifer hoch/runter, öffnen/schließen. Taster: Wiedergabe starten/stoppen. Langes Drücken (2 s): Automatische Endloswiedergabe.

Hinweis: Es existiert eine minimalisierte Version ohne zusätzliche Widerstände/LED sowie eine Version für das originale MeArm-Joystick-Board mit IR-Fernbedienung.

Quellcode (Version 1.3.1)

/* meArm analog joysticks v1.3.1 - UtilStudio.com Dez 2018
 * Zwei analoge Joysticks, vier Servos.
 * Verbesserte Koordinaten-Aufzeichnung, Bugfixes.
 * Pins:
 * Arduino | Stick1 | Stick2 | Base | Shoulder | Elbow | Gripper | Rec/Autoplay
 * GND     | GND    | GND    | Br   | Br       | Br    | Br
 * 5V      | VCC    | VCC    | Rd   | Rd       | Rd    | Rd
 * A0      | HOR    |        |      |          |       |
 * A1      | VER    |        |      |          |       |
 * PD2     | BTN    |        |      |          |       | Record
 * A2      |        | HOR    |      |          |       |
 * A3      |        | VER    |      |          |       |
 * PD3     |        | BTN    |      |          |       | Play
 * 11      |        |        | Yel  |          |       |
 * 10      |        |        |      | Yel      |       |
 * 9       |        |        |      |          | Yel   |
 * 6       |        |        |      |          |       | Yel
 * PD4     |        |        |      |          |       | LED
 */

#include <Servo.h>

bool repeatePlaying = false;
int delayBetweenCycles = 2000;

int basePin = 11, shoulderPin = 10, elbowPin = 9, gripperPin = 6;
int xdirPin = 0, ydirPin = 1, zdirPin = 3, gdirPin = 2;
int pinRecord = 2, pinPlay = 3, pinLedRecord = 4;
bool useInternalPullUpResistors = false;

const int buffSize = 512;
int startBase = 90, startShoulder = 90, startElbow = 90, startGripper = 0;
int posBase = 90, posShoulder = 90, posElbow = 90, posGripper = 0;
int lastBase = 90, lastShoulder = 90, lastElbow = 90, lastGripper = 90;
int minBase = 0, maxBase = 150;
int minShoulder = 0, maxShoulder = 150;
int minElbow = 0, maxElbow = 150;
int minGripper = 0, maxGripper = 150;

const int countServo = 4;
int buff[buffSize], buffAdd[countServo];
int recPos = 0, playPos = 0;
int buttonRecord = HIGH, buttonPlay = HIGH;
int buttonRecordLast = LOW, buttonPlayLast = LOW;
bool record = false, play = false, debug = false;
String command = "Manual";
int printPos = 0;
int buttonPlayDelay = 20, buttonPlayCount = 0;
bool ledLight = false;

Servo servoBase, servoShoulder, servoElbow, servoGripper;

void setup() {
  Serial.begin(9600);
  if (useInternalPullUpResistors) {
    pinMode(pinRecord, INPUT_PULLUP);
    pinMode(pinPlay, INPUT_PULLUP);
  } else {
    pinMode(pinRecord, INPUT);
    pinMode(pinPlay, INPUT);
  }
  pinMode(xdirPin, INPUT);
  pinMode(ydirPin, INPUT);
  pinMode(zdirPin, INPUT);
  pinMode(gdirPin, INPUT);
  pinMode(pinLedRecord, OUTPUT);

  servoBase.attach(basePin);
  servoShoulder.attach(shoulderPin);
  servoElbow.attach(elbowPin);
  servoGripper.attach(gripperPin);

  StartPosition();
  digitalWrite(pinLedRecord, HIGH);
  delay(1000);
  digitalWrite(pinLedRecord, LOW);
}

void loop() {
  buttonRecord = digitalRead(pinRecord);
  buttonPlay = digitalRead(pinPlay);

  // Autoplay-Erkennung (langes Drücken)
  if (buttonPlay == LOW) {
    buttonPlayCount++;
    if (buttonPlayCount >= buttonPlayDelay) repeatePlaying = true;
  } else buttonPlayCount = 0;

  // Play-Taster flankengetriggert
  if (buttonPlay != buttonPlayLast) {
    if (record) record = false;
    if (buttonPlay == LOW) {
      play = !play;
      repeatePlaying = false;
      if (play) StartPosition();
    }
  }

  // Record-Taster flankengetriggert
  if (buttonRecord != buttonRecordLast) {
    if (buttonRecord == LOW) {
      record = !record;
      if (record) { play = false; repeatePlaying = false; recPos = 0; }
      else if (debug) PrintBuffer();
    }
  }
  buttonPlayLast = buttonPlay;
  buttonRecordLast = buttonRecord;

  // Joystick einlesen & Deadzone
  float dx = map(analogRead(xdirPin), 0, 1023, -5.0, 5.0);
  float dy = map(analogRead(ydirPin), 0, 1023, 5.0, -5.0);
  float dz = map(analogRead(zdirPin), 0, 1023, 5.0, -5.0);
  float dg = map(analogRead(gdirPin), 0, 1023, 5.0, -5.0);
  if (abs(dx) < 1.5) dx = 0;
  if (abs(dy) < 1.5) dy = 0;
  if (abs(dz) < 1.5) dz = 0;
  if (abs(dg) < 1.5) dg = 0;

  posBase += dx;
  posShoulder += dy;
  posElbow += dz;
  posGripper += dg;

  // Wiedergabe-Modus
  if (play) {
    if (playPos >= recPos) {
      playPos = 0;
      if (repeatePlaying) { delay(delayBetweenCycles); StartPosition(); }
      else play = false;
    }
    bool endOfData = false;
    while (!endOfData) {
      if (playPos >= buffSize - 1) break;
      if (playPos >= recPos) break;
      int data = buff[playPos];
      int angle = data & 0xFFF;
      int servoNumber = data & 0x3000;
      endOfData = data & 0x4000;
      switch (servoNumber) {
        case 0x0000: posBase = angle; break;
        case 0x1000: posShoulder = angle; break;
        case 0x2000: posElbow = angle; break;
        case 0x3000: posGripper = angle; dg = posGripper - lastGripper; break;
      }
      playPos++;
    }
  }

  // Begrenzungen
  posBase = constrain(posBase, minBase, maxBase);
  posShoulder = constrain(posShoulder, minShoulder, maxShoulder);
  posElbow = constrain(posElbow, minElbow, maxElbow);
  posGripper = constrain(posGripper, minGripper, maxGripper);

  servoBase.write(posBase);
  servoShoulder.write(posShoulder);
  servoElbow.write(posElbow);

  bool waitGripper = false;
  if (dg < 0) { posGripper = minGripper; waitGripper = true; }
  else if (dg > 0) { posGripper = maxGripper; waitGripper = true; }
  servoGripper.write(posGripper);
  if (play && waitGripper) delay(1000);

  // Aufzeichnung bei Positionsänderung
  if (lastBase != posBase || lastShoulder != posShoulder ||
      lastElbow != posElbow || lastGripper != posGripper) {
    if (record && recPos < buffSize - countServo) {
      int buffPos = 0;
      if (lastBase != posBase) { buffAdd[buffPos] = posBase; buffPos++; }
      if (lastShoulder != posShoulder) { buffAdd[buffPos] = posShoulder | 0x1000; buffPos++; }
      if (lastElbow != posElbow) { buffAdd[buffPos] = posElbow | 0x2000; buffPos++; }
      if (lastGripper != posGripper) { buffAdd[buffPos] = posGripper | 0x3000; buffPos++; }
      buffAdd[buffPos - 1] |= 0x4000; // Endemarkierung
      for (int i = 0; i < buffPos; i++) buff[recPos + i] = buffAdd[i];
      recPos += buffPos;
    }
    command = "Manual"; printPos = 0;
    if (play) { command = "Play"; printPos = playPos; }
    else if (record) { command = "Record"; printPos = recPos; }
    Serial.print(command); Serial.print("\t");
    Serial.print(printPos); Serial.print("\t");
    Serial.print(posBase); Serial.print("\t");
    Serial.print(posShoulder); Serial.print("\t");
    Serial.print(posElbow); Serial.print("\t");
    Serial.print(posGripper); Serial.print("\t");
    Serial.print(record); Serial.print("\t");
    Serial.println(play);
  }

  lastBase = posBase; lastShoulder = posShoulder;
  lastElbow = posElbow; lastGripper = posGripper;

  // LED-Anzeige
  if (repeatePlaying) ledLight = !ledLight;
  else { if (ledLight) ledLight = false; if (record) ledLight = true; }
  digitalWrite(pinLedRecord, ledLight);
  delay(50);
}

void PrintBuffer() {
  for (int i = 0; i < recPos; i++) {
    int data = buff[i];
    int angle = data & 0xFFF;
    int servoNumber = data & 0x3000;
    bool endOfData = data & 0x4000;
    Serial.print("Servo="); Serial.print(servoNumber);
    Serial.print("\tAngle="); Serial.print(angle);
    Serial.print("\tEnd="); Serial.print(endOfData);
    Serial.print("\tData="); Serial.println(data, BIN);
  }
}

void StartPosition() {
  int angleBase = servoBase.read();
  int angleShoulder = servoShoulder.read();
  int angleElbow = servoElbow.read();
  int angleGripper = servoGripper.read();
  Serial.print(angleBase); Serial.print("\t");
  Serial.print(angleShoulder); Serial.print("\t");
  Serial.print(angleElbow); Serial.print("\t");
  Serial.println(angleGripper);
  posBase = startBase; posShoulder = startShoulder;
  posElbow = startElbow; posGripper = startGripper;
  servoBase.write(posBase);
  servoShoulder.write(posShoulder);
  servoElbow.write(posElbow);
  servoGripper.write(posGripper);
}

Schaltplan

Schaltbild für den Joystick-Controller (siehe Originalprojekt). Testaufbau mit zwei Servos – für vier Servos gemäß Schaltplan verdrahten.