Arduino Nano Magnetschwebung: Teile & Verdrahtungs-Anleitung

Weitere Details & Tipps in meinen „Makes“ auf Thingiverse:

• Levitator 3D-gedruckt: Make 201394
• Shield für Arduino Nano: Make 201420

Code

Levitator.ino – Einfache Version (ohne PID)

//=========================================================|
// Ekobots Innovation Ltda - www.ekobots.com.br |
// Juan Sirgado y Antico - www.jsya.com.br |
//---------------------------------------------------------|
// Program Magnetic Levitator - 2016/02/06 |
// All rights reserved 2016 |
//=========================================================|

int anaPin = 1;      // Analog Pin A1 (Hall-Sensor)
int digPin = 5;      // Digital Pin 5 (Elektromagnet via TIP120)
int subPin = 7;      // Digital Pin 7 (Taster: Wert verringern)
int addPin = 8;      // Digital Pin 8 (Taster: Wert erhöhen)

int anaVal = 0;      // Analogwert Hall-Sensor
boolean digVal = 0;  // Digitalwert Elektromagnet
int levVal = 228;    // Schwebepunkt-Wert (einzustellen!)
int dlyVal = 250;    // Delay Mikrosekunden

void setup() {
  Serial.begin(57600);
  Serial.println("Levitator by JSyA");
  Serial.println("Starting...");

  pinMode(digPin, OUTPUT);
  pinMode(subPin, INPUT_PULLUP);
  pinMode(addPin, INPUT_PULLUP);

  Serial.println("Started.");
}

void loop() {
  // Hall-Sensor lesen (Magnetfeldstärke)
  anaVal = analogRead(anaPin);

  // Schwebepunkt erhöhen
  if (digitalRead(addPin) == LOW) {
    levVal++;
    value_log();
    delay(250);
  }
  // Schwebepunkt verringern
  if (digitalRead(subPin) == LOW) {
    levVal--;
    value_log();
    delay(250);
  }

  // Vergleich: Sensorwert vs. Schwebepunkt
  if (anaVal < levVal) {
    digVal = LOW;   // Elektromagnet AN (Magnetfeld aufbauen)
  } else {
    digVal = HIGH;  // Elektromagnet AUS (Feld abbauen)
  }

  // Elektromagnet schalten
  digitalWrite(digPin, digVal);
  delayMicroseconds(dlyVal);
}

void value_log() {
  Serial.print("anaVal=["); Serial.print(anaVal); Serial.print("]-");
  Serial.print("digVal=["); Serial.print(digVal); Serial.print("]-");
  Serial.print("levVal=["); Serial.print(levVal); Serial.println("];");
}
//=========================================================|

Levitator_PID.ino – PID-Version (fortgeschritten)

//=========================================================|
// Ekobots Innovation Ltda - www.ekobots.com.br |
// Juan Sirgado y Antico - www.jsya.com.br |
//---------------------------------------------------------|
// Program Magnetic Levitator PID - 2016/10/06 |
// All rights reserved 2016 |
//=========================================================|

int anaPin = 1;
int digPin = 5;
int subPin = 7;
int addPin = 8;

int anaVal = 0;
int digVal = 0;
int levVal = 262;
int dlyVal = 10;
float timVal = 0;

// PID-Parameter
float setpoint = 0;
float measured_value = 0;
float output = 0;
float integral = 0;
float derivative = 0;
float error = 0;
float previous_error = 0;
float dt = 0.1;
float Kp = 1.0;
float Ki = 0.1;
float Kd = 0.01;

void setup() {
  Serial.begin(57600);
  Serial.println("Levitator by JSyA");
  Serial.println("Starting...");

  pinMode(digPin, OUTPUT);
  pinMode(addPin, INPUT_PULLUP);
  pinMode(subPin, INPUT_PULLUP);

  setpoint = levVal;
  Serial.println("Started.");
}

void loop() {
  anaVal = analogRead(anaPin);

  // PID-Berechnung
  measured_value = anaVal;
  error = setpoint - measured_value;
  integral += error * dt;
  derivative = (error - previous_error) / dt;
  output = (-Kp * error) + (-Ki * integral) + (-Kd * derivative);
  previous_error = error;

  // PWM-Wert für Elektromagnet (0-255)
  digVal += output;
  if (digVal < 0) digVal = 0;
  if (digVal > 255) digVal = 255;

  analogWrite(digPin, digVal);

  // Debug-Log alle 500ms (auskommentiert)
  // if ((millis() - timVal) > 500) { value_log(); timVal = millis(); }

  // Schwebepunkt per Taster ändern
  if (digitalRead(addPin) == LOW) {
    setpoint++;
    value_log();
    delay(250);
  }
  if (digitalRead(subPin) == LOW) {
    setpoint--;
    value_log();
    delay(250);
  }

  delayMicroseconds(dlyVal);
}

void value_log() {
  Serial.print("anaVal=["); Serial.print(anaVal); Serial.print("]-");
  Serial.print("digVal=["); Serial.print(digVal); Serial.print("]-");
  Serial.print("setpoint=["); Serial.print(setpoint); Serial.println("];");
}
//=========================================================|

Schaltpläne

Erstellt mit Fritzing: